Re: [PATCH] getpid/vfork/raise fix

[Andreas Schwab <schwab at suse dot de>]

Here are the corresponding changes for ia64.

Andreas.

2004-03-10  Andreas Schwab  <schwab@suse.de>

	* sysdeps/ia64/tcb-offsets.sym: Add PID.
	* sysdeps/unix/sysv/linux/ia64/vfork.S: New file.
	* sysdeps/unix/sysv/linux/ia64/pt-vfork.S: Properly handle PID
	cache.

--- nptl/sysdeps/ia64/tcb-offsets.sym.~1.5.~	2003-12-11 11:35:12.000000000 +0100
+++ nptl/sysdeps/ia64/tcb-offsets.sym	2004-03-09 10:49:45.000000000 +0100
@@ -1,5 +1,6 @@
 #include <sysdep.h>
 #include <tls.h>
 
+PID			offsetof (struct pthread, pid) - sizeof (struct pthread)
 MULTIPLE_THREADS_OFFSET offsetof (struct pthread, header.multiple_threads) - sizeof (struct pthread)
 SYSINFO_OFFSET		offsetof (tcbhead_t, private)
--- nptl/sysdeps/unix/sysv/linux/ia64/pt-vfork.S.~1.2.~	2003-12-11 11:35:12.000000000 +0100
+++ nptl/sysdeps/unix/sysv/linux/ia64/pt-vfork.S	2004-03-10 11:28:34.057587179 +0100
@@ -1,4 +1,4 @@
-/* Copyright (C) 2000, 2002, 2003 Free Software Foundation, Inc.
+/* Copyright (C) 2000, 2002, 2003, 2004 Free Software Foundation, Inc.
    This file is part of the GNU C Library.
 
    The GNU C Library is free software; you can redistribute it and/or
@@ -32,13 +32,22 @@
 ENTRY(__vfork)
 	.prologue	// work around a GAS bug which triggers if
 	.body		// first .prologue is not at the beginning of proc.
-	alloc r2=ar.pfs,0,0,2,0
+	alloc r2=ar.pfs,0,1,2,0
+	adds r14=PID,r13
+	;; 
+	ld4 loc0=[r14]
+	;;
+	sub r15=0,loc0
 	mov out0=CLONE_VM+CLONE_VFORK+SIGCHLD
 	mov out1=0		/* Standard sp value.			*/
 	;;
+	st4 [r14]=r15
 	DO_CALL (SYS_ify (clone))
+	cmp.eq p0,p7=0,r8
 	cmp.eq p6,p0=-1,r10
+	adds r14=PID,r13
 	;;
+(p7)	st4 [r14]=loc0
 (p6)	br.cond.spnt.few __syscall_error
 	ret
 PSEUDO_END(__vfork)
--- /dev/null	2004-02-28 23:52:18.000000000 +0100
+++ nptl/sysdeps/unix/sysv/linux/ia64/vfork.S	2004-03-10 09:36:47.000000000 +0100
@@ -0,0 +1,58 @@
+/* Copyright (C) 2000, 2002, 2004 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+
+#include <sysdep.h>
+#define _SIGNAL_H
+#include <bits/signum.h>
+#include <tcb-offsets.h>
+
+/* The following are defined in linux/sched.h, which unfortunately	*/
+/* is not safe for inclusion in an assembly file.			*/
+#define CLONE_VM        0x00000100      /* set if VM shared between processes */
+#define CLONE_VFORK     0x00004000      /* set if the parent wants the child to wake it up on mm_release */
+
+/* pid_t vfork(void); */
+/* Implemented as __clone_syscall(CLONE_VFORK | CLONE_VM | SIGCHLD, 0)	*/
+
+ENTRY(__vfork)
+	alloc r2=ar.pfs,0,1,2,0
+	adds r14=PID,r13
+	;; 
+	ld4 loc0=[r14]
+	;;
+	sub r15=0,loc0
+	cmp.eq p0,p6=0,loc0
+	;;
+(p6)	movl r15=0x80000000
+	mov out0=CLONE_VM+CLONE_VFORK+SIGCHLD
+	mov out1=0		/* Standard sp value.			*/
+	st4 [r14]=r15
+	;;
+	DO_CALL_VIA_BREAK (SYS_ify (clone))
+	cmp.eq p0,p7=0,r8
+	cmp.eq p6,p0=-1,r10
+	adds r14=PID,r13
+	;; 
+(p7)	st4 [r14]=loc0
+(p6)	br.cond.spnt.few __syscall_error
+	ret
+PSEUDO_END(__vfork)
+libc_hidden_def (__vfork)
+
+weak_alias (__vfork, vfork)

-- 
Andreas Schwab, SuSE Labs, schwab@suse.de
SuSE Linux AG, Maxfeldstraße 5, 90409 Nürnberg, Germany
Key fingerprint = 58CA 54C7 6D53 942B 1756  01D3 44D5 214B 8276 4ED5
"And now for something completely different."